The ElementLoad object represents a point or a distributed load applied to an element within the structure as part of a load case.  All the Element loads applied by a particular load case are stored in an ElementLoads collection within the LoadCase object.  These loads can be accessed via the ElementLoads property of the LoadCase object.  The properties and methods of the ElementLoad object are listed below.

The Application, Frame, Number, Label and Index properties as well as the Delete method are common to many objects and are described in Chapter 2.

An element point load is added to a load case using the AddPointLoad method of the ElementLoads collection.  The first parameter of this method specifies the element to which the load is to be applied.  The next parameter specifies the direction in which the load is applied.  This in an enumerated value of type mfDOF and has a default value of mfDOFy.  The next two parameters specify the magnitude and position of the load.  The values must be specified in the current force/moment and length units.  The position of the load is the distance of the load from the start of the element.  The final parameter in the AddPointLoad method specifies if the load is to be applied in the global or local element coordinate system.  By default, all element loads are applied in the elements local coordinate system.

For example, the following code adds a point load to element number 12.  The load is applied as part of the third load case and is positioned 1.5 units from the start of the element.  It is directed parallel to the global y-axis and has a magnitude of 20 units.

Dim myLoad as Multiframe.ElementLoad
 
With myFrame.LoadCases(1).ElementLoads

  ’Add downwards load of 20 units, 1.5 units from end of member
  set myLoad =.AddPointLoad(12,mfDOFy,-20.0,1.5,true)

End With

Remember that the units used in adding this load are those currently specified within the application.

A distributed load can be applied to an element using the AddLoad method of the ElementLoads collection.  This method takes 8 parameters, the first of which specifies the element to which the load is to be applied.  The next parameter specifies the direction in which the load is applied.  This in an enumerated value of type mfDOF and has a default value of mfDOFy.  The third parameter is an enumerated value of type mfLoadShape that describes the shape of the loading.  This enumerated type has values corresponding to uniform (mfLoadshapeUniform), linear (mfLoadshapeLinear), triangular (mfLoadshapeTriangular) and tri-linear (mfLoadshapeTriLinear) load shapes.

The next four parameters specify the magnitudes (F1 and F2) and distances (Distance1 and Distance2) of the loads from either end of the member.  These must be specified in the current force/moment and length units.  The interpretation of these quantities is dependent upon the shape of load been added to the element.  The definition of these parameters for each type of load shape is shown in the diagram below.  The parameters not required by a particular load shape will be ignored.

The final parameter of the AddLoad method specifies if the load is to be applied in the global or local element coordinate system.  By default, all element loads are applied in the elements local coordinate system.

The small script shown below demonstrates how the AddLoad method may be used to add the different types of loads.

Dim myLoad as Multiframe.ElementLoad
Dim myElLoads as Multiframe.ElementLoads
Dim L as double

’Get reference to element loads collection
set myElLoads = myFrame.LoadCases(1).ElementLoads

With myElLoads

  ’Add uniformly distributed load
  set myLoad =.AddLoad(12,mfDOFy,mfLoadshapeUniform,1.5,bGlobal:=true)

  ’Add linearly varying distributed load
  set myLoad =.AddLoad(12,3,mfLoadshapeLinear,1.5,0.5,2.5,0.5)

  ’Add triangular load
  L = myFrame.Elements(5).Length
  set myLoad =.AddLoad(5,2,mfLoadshapeTriangular,1.5,0.5*L,true)

  ’Add tri-linear load
  set myLoad=.AddLoad(5,2,mfLoadshapeTriLinear,1.5,0.3*L,1.5,0.3*L)

End With

The AddLoad method can also be used to add a point load to an element by specifying the shape of the load as mfLoadshapePoint.  In this case, the magnitude is specified by the parameter F1 while the loads position along the element is set using the Distance1 parameter.  A simple example follows.

Dim load as Multiframe.ElementLoad
Dim myLoads as Multiframe.ElementLoads
Dim L as double

’Get reference to element loads collection
With myFrame.LoadCases(1).ElementLoads

  ’Add a global point load at mid point of element
  L = myFrame.Elements(5).Length
  set load =.AddLoad(5,mfDOFz,mfLoadshapePoint,1.5,L/2,bGlobal:=true)

End With

Multiple element loads can be created using either the AddPointLoads or AddLoads methods of the ElementLoads collection.  These methods return an ElementLoadList containing each of the loads added to the collection.  The parameters of these methods correspond to the parameters of the AddPointLoad or AddLoad methods except that each parameter may be either an array, containing values for each of the new loads, or a single value that will be applied to each of the new loads.  Several examples of how this method may be used are as follows:

Dim myList as New Multiframe.ElementLoadList
Dim myElLoads as Multiframe.ElementLoads
Dim myVar as Variant
Dim L as Double

’Get reference to Element loads collection
set myElLoads = myFrame.LoadCases(1).ElementLoads

With myElLoads

  ’Add a single load
  set myList =.AddPointLoads(12,mfDOFy,-20.0,1.5,true)

  ’Add the same point load to elements 1,2 and 5
  set myList =. AddPointLoads (Array(1,2,5), mfDOFz,-5.0,2.0)

  ’Add two loads at node 12
  myVar = Array(mfDOFx, mfDOFy)
  set myList =.AddLoad(12,myVar,mfLoadshapeLinear,1.5,0.5,2.5,0.5)

End With

The first parameter of the AddPointLoads and AddLoads methods is a variant parameter identifying the element to which the loads are to be applied.  This parameter may specify the elements by using an integer index, an array of integer indices, an Element object, an Element List, or an Elements collection.

An element load can be modified via the ElementLoad object.  This object has properties describing the element to which the load is applied, the direction of the load, the magnitude and the position of the load.

The element to which the load is applied is identified by the Element property of the ElementLoad object.  This property returns the Element object corresponding the element at which the load is applied.

The DOF property controls the direction in which the load is applied.  The property is an enumerated value of type mfDOF.  The axes to which these degrees of freedom refer are specified by the Global property.  If this Boolean property is true then the load is applied in the direction of the global coordinate axes.  If the Global property is false, the load is directed along the local element axes that are specified by the direction and orientation of the element.  The direction and axes of the loading may also be specified using the Kind property.  This property is a character string describing the direction of loading and the axes to which the load is applied.

The shape of an element load is specified by the Shape property of the element load that is an enumerated value of type mfLoadShape.  This enumerated type has values corresponding to uniform, linearly varying, triangular and tri-linear distributed loads as well as a value representing a concentrated point load.  The magnitudes of the loads that describe this shape of load are referenced by the Value1 and Value2 properties of the ElementLoad object.  Similarly, the two distances that may be used to describe a particular shape of load as contained by the Dist1 and Dist2 properties the ElementLoad object.  The values of these properties are specified in terms of the current force units (Value1, Value2) and in the current length units (Dist1, Dist2) as set within the Multiframe application.  An example of how these properties may be changed is as follows

Dim myLoad as Multiframe.ElementLoad
 
’Get reference to node load
set myLoad = myFrame.LoadCases(1).ElementLoads(4)

’Change load to global distributed load applied in y-direction
myLoad.DOF = mfDOFy
myLoad.Shape = mfLoadshapeTriangular
myLoad.Value1 = 10.5
myLoad.Dist1 = myLoad.Element.Length/2.0
myLoad.Global = true

’Change direction such that load applied in local z direction
myLoad.Kind = ”Wz’”

The LoadCase, Frame and Application properties of the Element load object identify its parent objects.  These properties cannot be modified.